divert(-1)
# AnotherLevel - A FVWM2 Configuration
# Copyright (C) 1996, 1997 Red Hat Software, Inc
#
#	$Id: fvwm2rc.hostmenus.m4,v 1.1 1998/04/22 04:22:32 gafton Exp $	
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
# This work is derived from:
#       TheNextLevel
#       Copyright 1996 By Greg J. Badros <gjb@cs.duke.edu>
# distributed under GNU General Public License.
#
divert
###############################################################
# This file is m4-included by .fvwm2rc.menus, which was in turn
# included by .fvwm2rc.m4

define(`AddHostToMenu',`define(`m4_current_title',AddAmpersand(capitalize($1),$2))
AddToMenu $2 "m4_current_title`'MiniTitleIcon(display)" XTermOtherHost $1 $1
')

IfHostsDefined(`AddToMenu Hosts "Hosts" Title')

ifdef(`USER_HOST_LIST', `foreach(host,USER_HOST_LIST,`AddHostToMenu(host,Hosts)')',
ifdef(`AUTO_HOST_MENU',`esyscmd(awk < /etc/hosts "/localhost/ {next} \
	/^[^#]*[0-9]+\.[0-9]+\.[0-9]+\.[0-9]+/ {print \"AddHostToMenu(\"\$2 \",Hosts)\" }")'
))


# Continues the "Hosts" menu from above.
IfHostsDefined(`AddToMenu Hosts "" Nop')
IfHostsDefined(`
IfProgramExists(XRSH_OR_XON,`+ "AddAmpersand(Xrsh,Hosts)" FvwmForm Xrsh')
+ "AddAmpersand(Rlogin,Hosts)" FvwmForm Rlogin
')
